Background¶
Betti tables¶
Given an ideal $I \subset \mathbb{K}[x_1,\dots,x_n]$, a (minimal) free resolution "approximates" $R/I$. The betti table records the ranks of the summands appearing in the free resolution.
Example: $R = \mathbb{K}[x,y,z]$ and $I = \langle x^2, y^2, z^3 \rangle$ $$0 \leftarrow R/I \leftarrow R \leftarrow \substack{R(-2)^2 \\ \oplus \\ R(-3)} \leftarrow \substack{R(-4) \\ \oplus \\ R(-5)^2} \leftarrow R(-7) \leftarrow 0$$
kk = ZZ/32749
R = kk[x,y,z]
I = ideal(x^2, y^2, z^3)
F = res I
-- resolution and summands
print F
1 3 3 1
R <-- R <-- R <-- R <-- 0
0 1 2 3 4
-- differentials in the complex
print F.dd
1 3
0 : R <---------------- R : 1
| x2 y2 z3 |
3 3
1 : R <----------------------- R : 2
{2} | -y2 -z3 0 |
{2} | x2 0 -z3 |
{3} | 0 x2 y2 |
3 1
2 : R <--------------- R : 3
{4} | z3 |
{5} | -y2 |
{5} | x2 |
1
3 : R <----- 0 : 4
0
-- summands in free resolution
for i in 0..length(F) do print(toString(i) | ": " | toString flatten degrees F_i)
-- Betti table
print betti F
-- invariants from Betti table
print("Projective dimension of R/I: " | toString pdim (R^1/I))
print("Regularity of R/I: " | toString regularity(R^1/I))
0: {0}
1: {2, 2, 3}
2: {4, 5, 5}
3: {7}
0 1 2 3
total: 1 3 3 1
0: 1 . . .
1: . 2 . .
2: . 1 1 .
3: . . 2 .
4: . . . 1
Projective dimension of R/I: 3
Regularity of R/I: 4
Artinian rings¶
Definition: A $\mathbb{Z}$-graded $\mathbb{K}$-algebra $A$ is Artinian if $A_d = 0$ for $d \gg 0$.
Example: $A = \mathbb{K}[x,y,z] / \langle x^2,y^2,z^3 \rangle$
| $d$ | $0$ | $1$ | $2$ | $3$ | $4$ | $5$ | |
|---|---|---|---|---|---|---|---|
| $\text{gens}(A_d)$ | $1$ | $x$ $y$ $z$ |
$xy$ $xz$ $yz$ $z^2$ |
$xyz$ $xz^2$ $yz^2$ |
$xyz^2$ | $\emptyset$ | |
| $\text{dim}(A_d)$ | $1$ | $3$ | $4$ | $3$ | $1$ | $0$ |
kk = ZZ/32749
R = kk[x,y,z]
I = ideal(x^2, y^2, z^3)
A = R/I
-- why do by hand what you can do by computer...?
ds = {"d"} | for i in 0..5 list i
mons = {"gens(A_d)"} | for i in 0..5 list netList(flatten entries basis(i, A), Boxes=>false)
dims = {"dim(A_d)"} | for i in 0..5 list hilbertFunction(i, A)
print netList({ds} | {mons} | {dims}, HorizontalSpace=>2, VerticalSpace=>1, Alignment=>Center)
+-------------+-----+-----+-------+---------+----------+-----+ | | | | | | | | | d | 0 | 1 | 2 | 3 | 4 | 5 | | | | | | | | | +-------------+-----+-----+-------+---------+----------+-----+ | | | | | | | | | | | | | | 2 | | | gens(A_d) | 1 | x | x*y | x*y*z | x*y*z | | | | | y | x*z | 2 | | | | | | z | y*z | x*z | | | | | | | 2 | 2 | | | | | | | z | y*z | | | | | | | | | | | +-------------+-----+-----+-------+---------+----------+-----+ | | | | | | | | | dim(A_d) | 1 | 3 | 4 | 3 | 1 | 0 | | | | | | | | | +-------------+-----+-----+-------+---------+----------+-----+
-- Artinian => Hilbert series is a polynomial
print("Hilbert series: " | toString(hilbertSeries(A, Reduce=>true)))
Hilbert series: (1+3*T+4*T^2+3*T^3+T^4)/(1)
-- Artinian <=> Krull dim = 0
print("R/I = " | toString(describe(A)) |
" is Artinian: " | toString(dim(A) == 0))
R/I = R/(x^2,y^2,z^3) is Artinian: true
Gorenstein rings¶
Let $A = R/I$ be an Artinian $\mathbb{K}$-algebra.
Definition: The socle of $A$ is the ideal $(0 \colon \mathfrak{m}_A)$; its socle degree is the largest integer $d$ such that $A_d \neq 0$.
Definition: We say $A$ is Gorenstein if its socle is a one-dimensional $\mathbb{K}$-vector space.
Corollary: If $A$ is Gorenstein, then its Betti table is symmetric.
-- Betti table
print betti F
0 1 2 3
total: 1 3 3 1
0: 1 . . .
1: . 2 . .
2: . 1 1 .
3: . . 2 .
4: . . . 1
Fiber Products and Connected Sums¶
Definition: Let $A$, $B$, and $T$ be graded Artinian Gorenstein (AG) rings and let $\pi_A \colon A \to T$ and $\pi_B \colon B \to T$ be graded surjections. The fiber product is the pullback $A \times_T B = \{ (a,b) \, \colon \, \pi_A(a) = \pi_B(b) \}$. It is characterized by the degree-preserving exact sequence $$ 0 \longrightarrow A \times_T B \longrightarrow A \oplus B \longrightarrow T \longrightarrow 0.$$
Definition: If $A$, $B$, and $T$ have socle degrees $d$, $d$, and $e$, respectively, then the connected sum $A \#_T B$ is characterized by the short exact sequence of vector spaces $$ 0 \longrightarrow T(e-d) \longrightarrow A \times_T B \longrightarrow A \#_T B \longrightarrow 0.$$
Who cares?¶
Theorem [Ananthnarayan, Avramov, Moore; 2012]: (Roughly)
- If $A$ and $B$ are Cohen-Macaulay, then $A \times_T B$ is Cohen-Macaulay.
- If $A$ and $B$ are Gorenstein local rings, then $A \#_T B$ is Gorenstein.
Let $R = \mathbb{K}[x_1,\dots,x_m]$, $S = \mathbb{K}[y_1,\dots,y_n]$, and $Q = R \otimes S \cong \mathbb{K}[x_1,\dots,x_m,y_1,\dots,y_n]$.
Lemma: $$A \times_{\mathbb{K}} B \cong = \frac{Q}{\mathbf{x} \cap \mathbf{y} + \mathfrak{a} + \mathfrak{b}} \quad \text{and} \quad A \#_{\mathbb{K}} B \cong \frac{Q}{\mathbf{x} \cap \mathbf{y} + \mathfrak{a} + \mathfrak{b} + (s_A - s_B)},$$ where $s_A \in \text{socle}(A)$ and $s_B \in \text{socle(B)}$.
Example¶
$$A = \frac{\mathbb{K}[x,y,z]}{(x^3, y^4, z^4)} \quad \text{and} \quad B = \frac{\mathbb{K}[u,v]}{(u^5, y^5)}$$
$$A \times_{\mathbb{K}} B \cong \frac{\mathbb{K}[x,y,z,u,v]}{(xu,xv,yu,yv,zu,zv,x^3,y^4,z^4,u^5,v^5)}$$
$$A \otimes_{\mathbb{K}} B \cong \frac{\mathbb{K}[x,y,z,u,v]}{(xu,xv,yu,yv,zu,zv,x^3,y^4,z^4,u^5,v^5,x^2 y^3 z^3 + u^4 v^4)}$$
| $d$ | $0$ | $1$ | $2$ | $3$ | $4$ | $5$ | $6$ | $7$ | $8$ | |
|---|---|---|---|---|---|---|---|---|---|---|
| $\text{HF}(A)$ | $1$ | $3$ | $6$ | $9$ | $10$ | $9$ | $6$ | $3$ | $1$ | |
| $\text{HF}(B)$ | $1$ | $2$ | $3$ | $4$ | $5$ | $4$ | $3$ | $2$ | $1$ | |
| $\text{HF}(A \times_{\mathbb{K}} B)$ | $1$ | $5$ | $9$ | $13$ | $15$ | $13$ | $9$ | $5$ | $2$ | |
| $\text{HF}(A \otimes_{\mathbb{K}} B)$ | $1$ | $5$ | $9$ | $13$ | $15$ | $13$ | $9$ | $5$ | $1$ |
restart
kk = ZZ/32749
R = kk[x,y,z]
S = kk[u,v]
Q = kk[x,y,z,u,v]
I = ideal(x^3, y^4, z^4)
J = ideal(u^5, v^5)
xCapy = intersect(sub(ideal vars R, Q), sub(ideal vars S, Q))
bettiTables = apply({I, J, xCapy}, i -> minimalBetti i)
print netList({bettiTables}, HorizontalSpace=>2, VerticalSpace=>1, Alignment=>Center)
+------------------+----------------+--------------------+ | | | | | 0 1 2 3 | 0 1 2 | 0 1 2 3 4 | | total: 1 3 3 1 | total: 1 2 1 | total: 1 6 9 5 1 | | 0: 1 . . . | 0: 1 . . | 0: 1 . . . . | | 1: . . . . | 1: . . . | 1: . 6 9 5 1 | | 2: . 1 . . | 2: . . . | | | 3: . 2 . . | 3: . . . | | | 4: . . . . | 4: . 2 . | | | 5: . . 2 . | 5: . . . | | | 6: . . 1 . | 6: . . . | | | 7: . . . . | 7: . . . | | | 8: . . . 1 | 8: . . 1 | | | | | | +------------------+----------------+--------------------+
fiberProduct = xCapy + I + J
socle = ideal(x^2 * y^3 * z^3 + u^4 * v^4)
connectedSum = fiberProduct + ideal(x^2 * y^3 * z^3 + u^4 * v^4)
funBettiTables = apply({fiberProduct, connectedSum}, i -> minimalBetti i)
print netList({funBettiTables}, HorizontalSpace=>2, VerticalSpace=>1, Alignment=>Center)
+--------------------------+--------------------------+ | | | | 0 1 2 3 4 5 | 0 1 2 3 4 5 | | total: 1 11 25 24 11 2 | total: 1 12 29 29 12 1 | | 0: 1 . . . . . | 0: 1 . . . . . | | 1: . 6 9 5 1 . | 1: . 6 9 5 1 . | | 2: . 1 2 1 . . | 2: . 1 2 1 . . | | 3: . 2 4 2 . . | 3: . 2 4 2 . . | | 4: . 2 6 6 2 . | 4: . 2 6 6 2 . | | 5: . . 2 4 2 . | 5: . . 2 4 2 . | | 6: . . 1 2 1 . | 6: . . 1 2 1 . | | 7: . . . . . . | 7: . 1 5 9 6 . | | 8: . . 1 4 5 2 | 8: . . . . . 1 | | | | +--------------------------+--------------------------+
Betti numbers¶
Theorem: For any $i \geq 1$ there is an isomorphism of graded $\mathbb{K}$-vector spaces $$ \text{Tor}_i^Q(A \times_{\mathbb{K}} B)_j \cong \begin{cases} 0 & \text{if } j \leq i \\ \text{Tor}_i^Q(A)_{i+1} \oplus \text{Tor}_i^Q(B)_{i+1} \oplus \text{Tor}_i^Q(Q / \mathbf{x} \cap \mathbf{y})_{i+1} & \text{if } j = i+1 \\ \text{Tor}_i^Q(A)_j \oplus \text{Tor}_i^Q(B)_j & \text{if } j \geq i+2 \end{cases}. $$ In particular, $$P_{A \times_{\mathbb{K}} B}^Q(t,s) = \tilde{P}_A^Q(t,s) + \tilde{P}_B^Q(t,s) + P_{Q / \mathbf{x} \cap \mathbf{y}}^Q(t,s)$$ and $$\text{reg}(A \times_{\mathbb{K}} B) \leq \max(\text{reg}(A), \text{reg}(B)).$$
Corollary: Let $[x]_+ = \max(0,x)$, and for integers $a,b,c,d$, and a module $M$ over a ring $P$, let $$s_{a,b,c,d}^P(M) = \sum_{l=0}^{\min(a,b)-1} \binom{c}{[i-b]_+ + l} \beta_{\min(a,b)-l,d-l-[a-b]_+(M)}.$$ Then $$ \beta_{i,j}^Q(A \times_{\mathbb{K}} B) = \begin{cases} 0 & \text{if } j \leq i, (i,j) \neq 0 \\ 1 & \text{if } i = j = 0 \\ s_{i,m,n,i+1}^R(A) + s_{i,n,m,i+1}^S(B) + \binom{m+n}{i+1} - \binom{m}{i+1} - \binom{n}{i+1} & \text{if } j = i+1 \\ s_{i,m,n,j}^R(A) + s_{i,n,m,j}^S(B) & \text{if } j \geq i+2 \\ \end{cases}. $$
Theorem: Assume that $A$ and $B$ are AG $\mathbb{K}$-algebras such that $\text{reg}(A) = \text{reg}(B) = e \geq 3$. For any integer $i \geq 1$, there is an isomorphism of graded $\mathbb{K}$-vector spaces $$ \text{Tor}_i^Q(A \#_{\mathbb{K}} B)_j \cong \begin{cases} 0 & \text{if } j \leq i \text{ and } (i,j) \neq (0,0) \\ \mathbb{K} & \text{if } (i,j) = (0,0) \\ \text{Tor}_i^Q(A)_{i+1} \oplus \text{Tor}_i^Q(B)_{i+1} \oplus \text{Tor}_i^Q(Q / \mathbf{x} \cap \mathbf{y})_{i+1} & \text{if } j = i+1 \\ \text{Tor}_i^Q(A)_j \oplus \text{Tor}_i^Q(B)_j & \text{if } i+2 \leq j \leq i+e-2 \\ \text{Tor}_i^Q(A)_j \oplus \text{Tor}_i^Q(B)_j \oplus \text{Tor}_{m+n-i}^Q(Q / \mathbf{x} \cap \mathbf{y})_{m+n-i+1} & \text{if } j = i+e-1 \\ \mathbb{K} & \text{if } (i,j) = (m+n, e+m+n) \\ 0 & \text{if } j \geq e+i \text{ and } (i,j) \neq (m+n, e+m+n) \end{cases}. $$ Equivalently, $$P_{A \#_{\mathbb{K}} B}^Q(t,s) = \tilde{P}_A^Q(t,s) + \tilde{P}_B^Q(t,s) + P_{Q / \mathbf{x} \cap \mathbf{y}}^Q(t,s) + s^{m+n+e} t^{m+n} P_{Q / \mathbf{x} \cap \mathbf{y}}^Q(t^{-1}, s^{-1}).$$
Corollary: With the notation from before, we have $$ \beta_{i,j}^Q(A \#_{\mathbb{K}} B) = \begin{cases} 0 & \text{if } j \leq i \text{ and } (i,j) \neq 0 \\ 1 & \text{if } (i,j) = (0,0) \\ s_{i,m,n,i+1}^R(A) + s_{i,n,m,i+1}(B) + \binom{m+n}{i+1} - \binom{m}{i+1} - \binom{n}{i+1} & \text{if } j = i+1 \\ s_{i,m,n,j}^R(A) + s_{i,n,m,j}^S(B) & \text{if } i+2 \leq j \leq i+e-2 \\ s_{i,m,n,i+1}^R(A) + s_{i,n,m,i+1}(B) + \binom{m+n}{m+n-i-1} - \binom{m}{m-i-1} - \binom{n}{n-i-1} & \text{if } i \leq m+n, j = i+e-1 \\ 1 & \text{if } (i,j) = (m+n,e+m+n) \\ 0 & \text{if } j \geq e+i \text{ and } (i,j) \neq (m+n,e+m+n) \end{cases}. $$
More Results¶
Theorem: The two-summand case extends to arbitrarily many summands for both the fiber product.
Theorem: The same is true for the connected sum provided all of the summands have the same regularity $e \geq 3$.
Doublings¶
Definition [KKRSSY; 2021]:
[For the experts] Let $J \subset R$ be a homogeneous ideal of codimension $c$ such that $R/J$ is Cohen-Macaulay and $\omega_{R/J}$ is its canonical module. Assume $R/J$ satisfies the condition $G_0$ (it is Gorenstein at all its minimal primes). Let $I$ be an ideal of codimension $c+1$.
[For everybody] We say $I$ is a doubling of $J$ via $\psi$ if $\exists$ a s.e.s. of $R/J$ modules $$0 \rightarrow \omega_{R/J}(-d) \xrightarrow[]{\psi} R/J \rightarrow R/I \rightarrow 0.$$
Proposition [Bruns, Herzog; 1993]: If $I$ is a doubling, then $R/I$ is a Gorenstein ring.
restart
kk = ZZ/32749
Q = kk[x,y,z]
I = ideal(x^4)
J = ideal(y^4)
L = ideal(z^4)
varIntersect = ideal(x*y, x*z, y*z)
fiberProduct = varIntersect
connectedSum = fiberProduct + ideal(x^3 + y^3, x^3 + z^3)
bettiTables = apply({fiberProduct, connectedSum}, i -> minimalBetti i)
print netList({bettiTables}, HorizontalSpace=>2, VerticalSpace=>1, Alignment=>Center)
+----------------+------------------+ | | | | 0 1 2 | 0 1 2 3 | | total: 1 3 2 | total: 1 5 5 1 | | 0: 1 . . | 0: 1 . . . | | 1: . 3 2 | 1: . 3 2 . | | | 2: . 2 3 . | | | 3: . . . 1 | | | | +----------------+------------------+
Definition:
Example: The two-summand connected sum case is characterized by the short exact sequence $$ 0 \longrightarrow T(e-d) \longrightarrow A \times_T B \longrightarrow A \#_T B \longrightarrow 0.$$ So, $A \#_T B$ is a doubling of $A \times_T B$.
Theorem: If $A_i$ is a doubling of some $1$-dimensional Cohen-Macaulay algebra $\tilde{A}_i$, then $A_1 \#_{\mathbb{K}} \dots \#_{\mathbb{K}} A_r$ is a doubling of $\tilde{A}_1 \times_{\mathbb{K}} \dots \times_{\mathbb{K}} \tilde{A}_r$.